跪求战地2单机32人以上地图和模组

不需要这么麻烦，给你个我以前写的批处理，可以随便修改人数，修改到200都可以，只要你机器受的了

以下是批处理代码，保存到记事本，改用扩展名bat运行，即可随便更改,不懂可以联系我

@echo off

title 战地2修改器 QQ:48248199 & mode con cols=55 lines=30
echo    战地2修改器&echo.&echo.&echo.&echo.
echo  1:修改人数 2:修改复活次数  3:恢复默认
echo.&echo.&echo.&echo.
set/p elect=请输入对应的编号:
if %elect%==1 (
cls & echo    战地2人数修改&echo.&echo.&echo.&echo.
echo.&echo.&echo.
echo 提示:普通机器建议30到50之间,&echo    好的可以尝试64或者更高&echo.&echo.&echo.&echo.&echo.&echo.
set /p number=请输入人数上限值：
) else (if %elect%==2 (cls & echo    战地2复活次数修改&echo.&echo.&echo.&echo.
echo.&echo.&echo.
echo 数字愈大,双方阵营的兵力值愈少,数字小则是愈多.
echo 数值100 =200 双方阵营的兵力值
echo 数值500 =22 双方阵营的兵力值
echo 数值10 =2000 双方阵营的兵力值
echo 数值1 =9999 双方阵营的兵力值
echo.&echo.&echo.&echo.
set /p number2=请输入兵力值（复活次数）:
))
setlocal enabledelayedexpansion 
>%temp%\bf2.vbs echo Const ForWriting = 2
>>%temp%\bf2.vbs echo Set objFSO = CreateObject("Scripting.FileSystemObject")
>>%temp%\bf2.vbs echo Set objFile = objFSO.OpenTextFile("bf2.txt", ForWriting, True)
>>%temp%\bf2.vbs echo objFile.Write CreateObject("WScript.Shell").RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Electronic Arts\EA Games\Battlefield 2\InstallDir")
>>%temp%\bf2.vbs echo objFile.Close
%temp%\bf2.vbs
for /f "tokens=*" %%i in (bf2.txt) do (set BF2Path=%%i)
if not exist %BF2Path% echo 请先运行至少一次游戏或者本机器内没有战地2或者版本不相符 &pause>nul &exit
del /q bf2.txt
if not exist "%BF2Path%\mods\bf2\AI\备份" md "%BF2Path%\mods\bf2\AI\备份" & if not exist "%BF2Path%\mods\bf2\AI\备份\AIDefault.ai" copy /y "%BF2Path%\mods\bf2\AI\AIDefault.ai" "%BF2Path%\mods\bf2\AI\备份"
if not exist "%BF2Path%\mods\bf2\python\game\gamemodes\备份" md "%BF2Path%\mods\bf2\python\game\gamemodes\备份" & if not exist "%BF2Path%\mods\bf2\python\game\gamemodes\备份\gpm_cq.py" copy /y "%BF2Path%\mods\bf2\python\game\gamemodes\gpm_cq.py" "%BF2Path%\mods\bf2\python\game\gamemodes\备份"

if %elect%==1 (
if exist "%BF2Path%\mods\bf2\AI\temp.txt" del /q "%BF2Path%\mods\bf2\AI\temp.txt"
for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %BF2Path%\mods\bf2\AI\AIDefault.ai')do (
set "str=%%b"
if %%a == 8 (echo aiSettings.setMaxNBots %number% >>%BF2Path%\mods\bf2\AI\temp.txt) else (if %%a == 20 (echo aiSettings.setMaxNBots %number% >>%BF2Path%\mods\bf2\AI\temp.txt) else (if %%a == 19 (echo aiSettings.overrideMenuSettings 1 >>%BF2Path%\mods\bf2\AI\temp.txt) else (if %%a == 21 (echo aiSettings.maxBotsIncludeHumans 0 >>%BF2Path%\mods\bf2\AI\temp.txt) else (if %%a == 22 (echo aiSettings.setBotSkill 1.0 >>%BF2Path%\mods\bf2\AI\temp.txt) else (echo/!str! >>%BF2Path%\mods\bf2\AI\temp.txt) ))))

)
del /q %BF2Path%\mods\bf2\AI\AIDefault.ai & ren %BF2Path%\mods\bf2\AI\temp.txt AIDefault.ai
)

if %elect%==2 (
if exist "%BF2Path%\mods\bf2\python\game\gamemodes\temp.txt" del /q  "%BF2Path%\mods\bf2\python\game\gamemodes\temp.txt"
for /f "tokens=1,* delims=:" %%a in ('findstr /n .* "%BF2Path%\mods\bf2\python\game\gamemodes\gpm_cq.py"')do (
set "str1=%%b"
if %%a == 110 (echo/  return int^(mapDefaultTickets * ^(bf2.serverSettings.getTicketRatio^(^) ^/ %number2%.0^)^) >>"%BF2Path%\mods\bf2\python\game\gamemodes\temp.txt") else (echo/!str1! >>"%BF2Path%\mods\bf2\python\game\gamemodes\temp.txt")
)
del /q "%BF2Path%\mods\bf2\python\game\gamemodes\gpm_cq.py" & ren "%BF2Path%\mods\bf2\python\game\gamemodes\temp.txt" gpm_cq.py
)

if %elect%==3 (cls & echo    战地2恢复原始数据&echo.&echo.&echo.&echo.
echo    此项设置恢复本机战地2里原本的数据，
echo    如果想要恢复成出厂设置可以手动通过
echo      1和2选项设置：
echo.&echo.&echo.&echo.
echo 出厂人数值（32/64） 原始兵力值（复活次数）（100）
echo.&echo.&echo.&echo.&echo.&echo  [按任意键]恢复本机电脑战地2里原本的数据 & pause>nul
rem del /q "%BF2Path%\mods\bf2\AI\AIDefault.ai"
if exist "%BF2Path%\mods\bf2\AI\备份\AIDefault.ai"   copy /y "%BF2Path%\mods\bf2\AI\备份\AIDefault.ai" "%BF2Path%\mods\bf2\AI"
if exist "%BF2Path%\mods\bf2\python\game\gamemodes\备份\gpm_cq.py" copy /y "%BF2Path%\mods\bf2\python\game\gamemodes\备份\gpm_cq.py" "%BF2Path%\mods\bf2\python\game\gamemodes"
rem rd /s "%BF2Path%\mods\bf2\AI\备份"
rem rd /s "%BF2Path%\mods\bf2\python\game\gamemodes\备份"
)
for /l %%i in (3,-1,1) do (
cls&echo.&echo.&echo.&echo.&echo.&echo        操作完毕,%%i秒后回到主界面。
ping /n 2 127.1>nul
)
%0 & exit

看这个视频，要不要这张地图 64人，无限飞机 http://www.aipai.com/c5/Pzo5KCclI2gnaiQo.html