IP切换批处理怎么写

答案:2 悬赏:70 手机版

解决时间 2021-03-22 05:17

提问者网友：爱了却不能说
2021-03-21 11:10

IP切换批处理怎么写

最佳答案

五星知识达人网友：话散在刀尖上
2021-03-21 11:52

使用批处理来切换IP地址，需要使用netsh命令，Netsh (Network Shell) 是windows系统本身提供的功能强大的网络配置命令行工具，是命令行脚本实用工具，它允许从本地或远程显示或修改当前正在运行的计算机的网络配置。批处理如下：
@ECHO OFF
CLS
color 0a
Title 切换IP批处理工具

:menu
cls
echo.
echo          切换IP批处理工具主菜单
echo         ===========================
echo.
echo         0、IP地址1（192.168.1.2）
echo         1、IP地址2（自动获取）
echo         e、退   出
echo.
:cl
echo.
set /p choice=         请选择要进行的操作，然后按回车:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="0" goto s0
if /i "%choice%"=="1" goto s1
if /i "%choice%"=="e" goto EX
echo.
echo         选择无效，请重新输入
echo.
goto cl
:s0
netsh interface ip set address name="本地连接" source=static addr=192.168.1.2 mask=255.255.255.0
netsh interface ip set address name="本地连接" gateway=192.168.1.254 gwmetric=0
netsh interface ip set dns name="本地连接" source=static addr=202.106.0.20 register=PRIMARY
netsh interface ip set wins name="本地连接" source=static addr=none
goto menu
:s1
netsh interface ip set address name="本地连接" source=dhcp
netsh interface ip set dns name="本地连接" source=dhcp register=PRIMARY
netsh interface ip set wins name="本地连接" source=dhcp
goto menu
:EX
exit

全部回答

1楼网友：走死在岁月里
2021-03-21 12:09

@echo 切换IP到公司所用
@echo off
netsh interface ip set address name="本地连接" source=static addr=10.20.166.135 mask=255.255.255.0
netsh interface ip set address name="本地连接" gateway=10.20.166.254 gwmetric=0
netsh interface ip set dns name="本地连接" source=static addr=221.12.1.228 register=PRIMARY
netsh interface ip add dns name="本地连接" addr=221.12.65.228 index=2
netsh interface ip set wins name="本地连接" source=static addr=none

把上面的IP和网关以及DNS修改为你使用的。

下面这个在家里使用：

家里.bat

@echo 切换成动态IP地址
@echo off
netsh interface ip set address name="本地连接" source=dhcp
netsh interface ip set dns name="本地连接" source=dhcp register=PRIMARY
netsh interface ip set wins name="本地连接" source=dhcp

我要举报

如以上回答内容为低俗、色情、不良、暴力、侵权、涉及违法等信息，可以点下面链接进行举报！

点此我要举报以上问答信息