开机时，UBAT没有值，进入不了系统
- 提问者网友：遁入空寂
- 2021-04-25 10:41
- 五星知识达人网友：执傲
- 2021-04-25 12:01
奇怪、我记得我这问题回答过的啊？
批处理清除ubat病毒，新建个文本文档，把下面的代码复制下来，另存为.bat为后缀的文件也就是批处理文件，然后双击运行就可以了。
@echo off
title 忆林子--清除ubat病毒
color 0a
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo 病毒说明
echo 该病毒会在C:\windows\ 目录下建立以下文件
echo inf.tem,s.vbe,u.bat,u.vbe,uhere-01.txt
echo.
echo 其他文件如下
echo c:\已经被反U盘病毒的“病毒”感染.txt
echo C:\WINDOWS\system32\CatRoot2\tmp.edb
echo.
echo 然后在每个盘建立以下文件
echo *.sk,autorun.inf,s.vbe,u.bat,u.vbe
echo.
echo 其中autorun.inf这个文件用文本编辑器打开后的代码是
echo [AutoRun]
echo open=wscript.exe u.vbe
echo shell\open\Command=wscript.exe u.vbe
echo shell\explore\Command=wscript.exe u.vbe
echo shell\find\Command=wscript.exe u.vbe
echo.
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo.
set /p k= 按回车键开始杀毒...
cls
taskkill /im wscript.exe /f
for %%d in (inf.tem,s.vbe,u.bat,u.vbe,uhere-01.txt) do if exist c:\windows\%%d attrib -s -h -r c:\windows\%%d
for %%d in (inf.tem,s.vbe,u.bat,u.vbe,uhere-01.txt) do if exist c:\windows\%%d del c:\windows\%%d /q
rd c:\windows\bakfiles /s /q
if exist "%userprofile%\..\All Users\「开始」菜单\程序\启动\u.vbe" del "%userprofile%\..\All Users\「开始」菜单\程序\启动\u.vbe" /q
for %%f in (autorun.inf,s.vbe,u.bat,u.vbe) do for /D %%d in (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) do if exist %%d:\%%f attrib -s -h -r %%d:\%%f
for %%f in (autorun.inf,s.vbe,u.bat,u.vbe) do for /D %%d in (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) do if exist %%d:\%%f del %%d:\%%f /q
for /D %%d in (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) do if exist %%d:\*.sk attrib -s -h -r %%d:\*.sk
for /D %%d in (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) do if exist %%d:\*.sk del %%d:\*.sk /q
del "c:\已经被反U盘病毒的“病毒”感染.txt" /q
del "C:\WINDOWS\system32\CatRoot2\tmp.edb" /q
reg delete "HKLM\SOFTWARE\Classes\.edb" /f
reg delete "HKLM\SOFTWARE\Classes\.tem" /f
reg delete "HKLM\SOFTWARE\Classes\.sk" /f
reg delete "HKLM\SOFTWARE\Classes\edb_auto_file" /f
reg delete "HKLM\SOFTWARE\Classes\tem_auto_file" /f
reg delete "HKLM\SOFTWARE\Classes\sk_auto_file" /f
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.edb" /f
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.tem" /f
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.vbe" /f
cls
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo.
echo 病毒清除完毕，按回车键开始解决分区无法双击打开的问题.
echo.
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
set /p test=
cls
@echo off
title 忆林子--解决分区无法打开
color 0a
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo.
echo 例如：D盘无法打开则输入 d,你也可以
echo 输入d,e,f这样来同时对d,e,f等多个分区操作.
echo.
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
set /p input=[请输入无法打开的分区的盘符]
if /i "%input%"=="c" goto :特殊
for /d %%i in (%input%) do cacls %%i:\autorun.inf /c /e /p everyone:f
for /d %%i in (%input%) do attrib -s -h -r %%i:\autorun.inf
for /d %%i in (%input%) do del %%i:\autorun.inf /q
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /v CheckedValue /f
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /v CheckedValue /t reg_dword /d 1 /f
cls
for /d %%i in (%input%) do chkdsk %%i: /f /x
cls
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo.
set /p tmp= 操作结束,按回车键退出该程序。
:exit
exit
:特殊
attrib -s -h -r %input%:\autorun.inf
del %input%:\autorun.inf /q
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo.
echo 操作成功结束，请重启，然后就可以双击就可以打开了。
echo 如果重启之后，还是无法双击打开的话，说明你的电脑
echo 里还有病毒，请先杀毒。然后再运行该程序。
echo.
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
set /p tmp= 操作结束，按回车键退出该程序。